Gradle versions

Some older skills might be incompatible with newer versions of IntelliJ due to a lack of backwards compatability in the later Gradle-versions.

Updating older skills

In you skill project you should have a file called build.gradle. You will need to update this file to contain this:

plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.9.24'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}
java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(8)
    }
}
repositories {
    mavenCentral()
    maven { url "https://s3-eu-west-1.amazonaws.com/furhat-maven/releases" }
    maven { url "https://repo.gradle.org/gradle/libs-releases" }
    maven { url "https://repo1.maven.org/maven2/" }
}
dependencies {
    implementation 'com.furhatrobotics.furhatos:furhat-commons:2.8.4'
}
Properties properties = new Properties()
properties.load(project.file('skill.properties').newDataInputStream())
version = properties.getProperty('version')
def skillName = properties.getProperty('name')
shadowJar {
    archiveBaseName.set(skillName)
    archiveVersion.set(project.version.toString())
    archiveClassifier.set("")
    archiveExtension.set('skill')
    from "skill.properties"
    from "assets"
    exclude("/Log4j2Plugins.dat", "/node_modules")
    mergeServiceFiles()
}

Attention

Make sure to add your specific dependencies here:

dependencies {
    implementation 'com.furhatrobotics.furhatos:furhat-commons:2.8.4'
}

But make sure to keep

implementation 'com.furhatrobotics.furhatos:furhat-commons:2.8.4'